Here I demonstrate how to find the polar and singular value decompositions of a matrix A.  I take as my example

MatrixForm[A={{1.,1.},{0,1.}}]

First I compute A* A:

MatrixForm[Asqr = Transpose[A].A]

Then I get the eigenvalues and corresponding eigenvectors of this.  The square roots of the eigenvalues will be my singular values.

{svs,svecs}=Eigensystem[Asqr]

svs =Sqrt[svs]

MatrixForm[svecs =Transpose[svecs]]

Hence the singular values are 1.62 and .62 with corresponding (normalized) eigenvectors (.53,.85) and (.85,-.53).

This allows me to compute | A | (i.e. the square root of A*A):

MatrixForm[absA = svecs.DiagonalMatrix[svs].Transpose[svecs]]

As this is invertible, I get the isometry U in the polar decomposition by multiplying A (on the right) by the inverse of absA:

MatrixForm[U = A.Inverse[absA]]

Thus the polar decomposition is A = U.absA, where U and absA are as just computed.  Now for the singular value decomposition, I also need to know the normalized images of the eigenvectors of A*A under A:

MatrixForm[W = A.svecs]

MatrixForm[W = Transpose[Map[Normalize,Transpose[W]]]]

Thus the singular value decomposition is W.Sig.V*, where W is as above and

MatrixForm[Sig = DiagonalMatrix[svs]]

MatrixForm[V = svecs]

MatrixForm[W.Sig.Transpose[V] ]

which is (almost) right.