* Missing.sav is an extract from the 1991 General Social Survey.
get file = 'Missing.sav'.

* Part 1.  Do frequencies on the original vars. Look at MD
* patterns, problems with coding.
FREQUENCIES VARS = RINCOME EDUC AGE SEX RACE PAEDUC/
                         STATISTICS = DEFAULT.

* Part 2.  I don't like the way RINCOME is coded.  I also don't think the
* MD categories are quite right.  Create a new variable, INCOME, 
* that is coded better.
RECODE RINCOME (1=0.5)  (2=2.0) (3=3.0) (4=4.5) (5=5.5)
               (6=6.5) (7=7.5) (8=9) (9=12.5) (10=17.5)
               (11=22.5) (12=25.0) 
               (0 = 97) (98,99=99) (13=98) into INCOME.
MISSING VALUES INCOME (99 97 98).
VALUE LABELS INCOME  
                     97 "Not Applicable"
                     98 "Refused"
                     99 "NA or DK".
FREQUENCIES VARIABLES = INCOME/ STATISTICS = DEFAULT.

* Part 3.  Let's fix the RACE and SEX variables too.  Even though race
* has 3 categories, I think it is better to only make one dummy.
RECODE RACE (1 = 1)(Else = 0) into WHITE/ 
         SEX (1 = 1) (ELSE = 0) INTO MALE.
FREQUENCIES VARIABLES = WHITE MALE/ STATISTICS = DEFAULT.

* Part 4.  Create a modified PAEDUC2 that I can use later.  Create
* an MD indicator.
DO IF (MISSING (PAEDUC)).
   COMPUTE MDPAEDUC=1.
   COMPUTE PAEDUC2=10.88.
ELSE.
   COMPUTE MDPAEDUC=0.
   COMPUTE PAEDUC2 = PAEDUC.
END IF.
FREQUENCIES VARIABLES = PAEDUC2 MDPAEDUC/ STATISTICS = DEFAULT.

* Part 5.  Listwise deletion of MD.
REGRESSION VARS INCOME EDUC AGE MALE PAEDUC WHITE 
     /MISSING LISTWISE
     /STATISTICS DEF CI
     /DESCRIPTIVES
     /DEP INCOME
     /ENTER EDUC AGE MALE PAEDUC WHITE .

* Part 6.  Pairwise deletion of MD.
REGRESSION VARS INCOME EDUC AGE MALE PAEDUC WHITE 
     /MISSING PAIRWISE
     /STATISTICS DEF CI
     /DESCRIPTIVES
     /DEP INCOME
     /ENTER EDUC AGE MALE PAEDUC WHITE .

* Part 7.  Mean substitution of MD (both IVs and DVs).  Seems questionable for 
* the DV.
REGRESSION VARS INCOME EDUC AGE MALE PAEDUC WHITE 
     /MISSING MEANSUBSTITUTION
     /STATISTICS DEF CI
     /DESCRIPTIVES
     /DEP INCOME
     /ENTER EDUC AGE MALE PAEDUC WHITE .

* Part 8.  Mean substitution, Father's education only, without and then with an MD indicator.
* The final regression will give us an idea of whether or not the MD in PAEDUC is missing
* on a random basis.
REGRESSION VARS INCOME EDUC AGE MALE PAEDUC2 MDPAEDUC WHITE 
     /MISSING LISTWISE
     /STATISTICS DEF CI
     /DESCRIPTIVES
     /DEP INCOME
     /ENTER EDUC AGE MALE PAEDUC2 WHITE 
     /ENTER MDPAEDUC.