* Change next line to the appropriate directory.
GET FILE='D:\SOC63993\homework\nonlinhw.sav'.


********** Part 1.
graph Title = "Plot of X1 with Y1" /scatterplot = x1 with y1.
* Curve Estimation.
TSET NEWVAR=NONE .
CURVEFIT /VARIABLES=y1 WITH x1
  /CONSTANT
  /MODEL=LINEAR quadratic 
  /PLOT FIT.

* Based on the above, we do the following compute.
compute x2 = x1**2.

REGRESSION
  /STATISTICS DEF cha
  /DEPENDENT y1
  /METHOD=ENTER x1/ Enter x2.

********** Part 2.
graph Title = "Plot of X1 with Y2" /scatterplot = x1 with y2.
* Curve Estimation.
TSET NEWVAR=NONE .
CURVEFIT /VARIABLES=y2 WITH x1
  /CONSTANT
  /MODEL=LINEAR growth
  /PLOT FIT.

* Based on the above, we compute the following.
compute lny2 = ln(y2).

REGRESSION
  /DEPENDENT y2
  /METHOD=ENTER x1  .

REGRESSION
  /DEPENDENT lny2
  /METHOD=ENTER x1  .

********** Part 3.
graph Title = "Plot of X1 with Y3" /scatterplot = x1 with y3.
* Curve Estimation.
TSET NEWVAR=NONE .
CURVEFIT /VARIABLES=y3 WITH x1
  /CONSTANT
  /MODEL=LINEAR 
  /PLOT FIT.

* Based on the above, we compute the following.
if (x1 le 0) breakpt = 0.
if (x1 gt 0) breakpt = 1.
compute breakx1 = breakpt * x1.

REGRESSION
  /STATISTICS DEF CHA
  /DEPENDENT y3
  /METHOD=ENTER x1/ Enter breakpt breakx1  .

******** Part 4.
* As this shows, a polynomial model would also be plausible for y3.
* In practice, it is often hard to tell just from the scatterplot what
* transformation is best, so theory is important.
CURVEFIT /VARIABLES=y3 WITH x1
  /CONSTANT
  /MODEL=LINEAR Quadratic
  /PLOT FIT.