h=method() -- computes the generators of H^1(Amitsur complex)
h(ZZ,Ideal,Ideal):=(n,J,JJ)->
(
     sbs1=basis(n,S2);
     mn=degree source sbs1;
     q=module S3/JJ;
     ff=S3^{mn:-n};
     mat=fxy(sbs1)+fyz(sbs1)-fxz(sbs1);
     ke=kernel map(q,ff,mat);
     BB=gens ke;
     BB=compress retS BB;
     mp=map(fxy(sbs1))*BB;
     sbt=basis(n,S1);
     Dn=ideal(fx1(sbt)-fy1(sbt))+J;
     zz=mingens ideal(fss1(mp)%Dn);
     zz
)

k = 2
kk = ZZ
S1 = kk[x_1..x_k]
S2 = kk[x_1..x_k,y_1..y_k]
S3 = kk[x_1..x_k,y_1..y_k,z_1..z_k]

use S3
fx = map(S3,S1,{x_1..x_k})
fy = map(S3,S1,{y_1..y_k})
fz = map(S3,S1,{z_1..z_k})
use S2
fx1 = map(S2,S1,{x_1..x_k})
fy1 = map(S2,S1,{y_1..y_k})
fss1 = map(S2,S3,{x_1..x_k,y_1..y_k,k:0})
retS1 = map(kk,S2,{2*k:0})
use S3
fxy = map(S3,S2,{x_1..x_k,y_1..y_k})
fxz = map(S3,S2,{x_1..x_k,z_1..z_k})
fyz = map(S3,S2,{y_1..y_k,z_1..z_k})
retS = map(kk,S3,{3*k:0})

use S1 -- S1 = C = ZZ[x_1,x_2]
i = matrix{{x_1^2,x_1*x_2-x_2^2,x_2^3}} -- f1, f2, f3; B = ZZ[f1,f2,f3]

J = ideal (fx1(i)-fy1(i)); -- S2/J = C\otimes_B C
JJ = ideal (fxy(gens J),fxz(gens J)); -- S3/JJ = C\otimes_B C\otimes_B C

n=5 -- the degree where the nontrivial 1-cocycle lives

In = super basis(n,J);  -- basis for degree n of J
bs1 = basis(n,S1); -- basis of the space of forms of degree 5 in C
Dn = (fx1(bs1)-fy1(bs1))|In; -- In + coboundaries
bs2 = basis(n,S2); -- basis of the space of forms of degree 5 in S2 = C\otimes C

lbs2 = numgens source bs2
lDn = numgens source Dn

q = module S3/JJ; -- C\otimes_B C\otimes_B C
ff = S3^{lbs2:-n}; 
mat = fxy(bs2)+fyz(bs2)-fxz(bs2); -- the differential d_1 in the Amitsur complex
BB = compress retS(gens kernel map(q,ff,mat)); -- cocycles of degree 5

mat = mutableMatrix(kk,lbs2,lDn)
for idn from 0 to lDn-1 do
(
     po = Dn_idn_0;
     for isbs from 0 to lbs2-1 do
     	  mat_(isbs,idn) = retS1(po//bs2_isbs_0);
)
mat = matrix(mat); -- the differential d_0 in the Amitsur complex

end

restart
load "noneffective.m2"

prune cokernel BB -- The ZZ-module of 1-cocycles of degree 5 is a direct summand in C_5
prune cokernel mat -- The ZZ-module of 1-coboundaries of degree 5 is a direct summand in C_5
minimalPresentation subquotient(BB,mat) -- The first Amitsur cohomology group is free of rank 1

(h(5,J,JJ))_0_0 -- the cocycle f
factor oo -- its representation as a product