Problem Set 1

Prob 1

Start with a general function of θ and ϕ,  g =ψ(θ,ϕ)

g  =  ψ[θ, ϕ]

Evaluate lsq = (L^2)ψ(θ,ϕ)

lsq  = 
      Simplify[ - (Csc[θ] 
                D[Sin[θ] 
                    D[g, θ], θ] +  (Csc[θ])^2 
                 D[D[g, ϕ], ϕ])]

Evaluate  lz = (Subscript[L, z]) ψ(θ,ϕ)  and   lz2 = (Subscript[L, z]^2) ψ(θ,ϕ)

lz  =  I D[g, ϕ]

lz2  =  I D[lz, ϕ]

Introduce the function  lpg = (Subscript[L, + ])ψ(θ,ϕ)

lpg  =   E^(I ϕ) (D[g, θ] +  
            I Cot[θ] D[g, ϕ])

Now,  evaluate   lmp  = \(TraditionalForm\`\(L\_-\)\)[lpg] = \(TraditionalForm\`\(L\_-\)\) \(TraditionalForm\`\(L\_+\)\) ψ(θ,ϕ)

lmp  =  
      Simplify[ 
        E^(-I ϕ) (-D[lpg, θ] +  
              I Cot[θ] D[lpg, ϕ])]

With the aid of this, we can determine  form1 =  (\(TraditionalForm\`\(L\_-\)\) \(TraditionalForm\`\(L\_+\)\) +  (Subscript[L, z]^2)- (Subscript[L, z])) ψ(θ,ϕ)

form1  =  Simplify[lmp  +  lz2  -  lz]

Test for equality of  (\(TraditionalForm\`\(L\_-\)\) \(TraditionalForm\`\(L\_+\)\) +  (Subscript[L, z]^2)- (Subscript[L, z])) ψ(θ,ϕ)  and  (L^2)ψ(θ,ϕ)

form1  ===  lsq

Now reverse the steps above and evaluate  form2 = (\(TraditionalForm\`\(L\_+\)\) \(TraditionalForm\`\(L\_-\)\) +  (Subscript[L, z]^2)+ (Subscript[L, z])) ψ(θ,ϕ)

lmg  =   E^(-I ϕ) (- D[g, θ] +  
            I Cot[θ] D[g, ϕ])

lpm  =  
      Simplify[ 
        E^(I ϕ) (D[lmg, θ] +  
              I Cot[θ] D[lmg, ϕ])]

form2  =  Simplify[lpm +  lz2  +  lz]

Test for equality of  (\(TraditionalForm\`\(L\_+\)\) \(TraditionalForm\`\(L\_-\)\) +  (Subscript[L, z]^2)+ (Subscript[L, z])) ψ(θ,ϕ)  and  (L^2)ψ(θ,ϕ)

form2  ===  lsq

We have therefore established the identity of the operators in both cases.

Prob 2

Set  l = 4  since this is the specific case of interest (you could use 1, 2 ... as well)

l  =  4

Generate a table of formulas from Eq(1.36) using Cos[θ] = x to simplify the differentiation

Table[(-1)^l/l!/
          2^l Sqrt[(2 l + 
                1) (l + 
                    m)!/(2 (l - 
                        m)!)] (1/(Sin[θ])^
              m) D[(1 - x^2)^l, {x, l - m}], {m, 0, l}]

Substitute x=cos(θ) into above table and simplify the results

posf  =  FullSimplify[% /.  x ->  Cos[θ]]

Obtain a table of formulas for  Y[l,m].  Note:  The factor (-1)^(3m+Abs[m]) reduces to
(-1)^m for m<0  but reduces to  (-1)^(2m) == +1 for m>0.

tab1  = 
      Table[(-1)^((3 m + Abs[m])/2) Sqrt[
            1/(2 Pi)] E^(I m ϕ) FullSimplify[
            posf[[Abs[m] + 1]]], {m, -l, l}]

Make a table of spherical harmonics generated by mathematica

tab2  =  
      Table[SphericalHarmonicY[l, m, θ, ϕ], {m, -l, 
          l}]

Some of these formulas look the same but others are different. Are they equivalent? Let us expand both and test for equality.

Table[
      TrigExpand[tab1[[m]]] === TrigExpand[tab2[[m]]], {m, 1, 
        2  l + 1}]

Check orthonormality

Table[
      Integrate[
        Sin[θ] Integrate[ 
            Conjugate[ tab1[[i]]] tab1[[j]], {ϕ, 0, 
              2 Pi}], {θ, 0, Pi}], {i, 1, 2 l + 1}, {j,  1,  
        2 l + 1}]

MatrixForm[%]