Integration of the polarization averaged quadrupole matrix element over photon angles.

After summing over photon polarization directions, the contribution of the quadrupole matrix element to the transition rate is |\(\(Rzx\)\( | \^2\)\)+|Rzy\( | \^2\), where Rij is the quadrupole matrix element in a frame {x'y'z'} with \(TraditionalForm\`k\&^\) is along z' and \(TraditionalForm\`ϵ\&^\)  in the {x',y'} plane. We want to transform this polarization sum to a general {x,y,z} coordinate system and integrate over photon angles. To this end, we introduce the matrix "a" that transforms from coordinates {x,y,x} to  coordinates {x',y',z'}

a  =  {{Cos[ϕ], Sin[ϕ], 
          0}, {-Cos[θ] Sin[ϕ], Cos[θ] Cos[ϕ], 
          Sin[θ]}, {Sin[θ] Sin[ϕ], -Sin[θ] Cos[ϕ], Cos[θ]}}

a // MatrixForm

Let Q be the quadrupole matrix in {xyz} system

Q  =  {{Qxx, Qxy, Qxz}, {Qxy, Qyy, Qyz}, {Qxz, Qyz, Qzz}}

Let R be the quadrupole matrix  in the rotated system (\(TraditionalForm\`k\&^\) along z'}

R  =  a . Q . Transpose[a]

Introduce the complex conjugates of Q and R

Qcc  =  Conjugate[Q]

Rcc  =  a  .  Qcc  .  Transpose[a]

Rzx  =  R[[3, 1]]

Rzy  =  R[[3, 2]]

Rzxcc  =  Rcc[[3, 1]]

Rzycc  =  Rcc[[3, 2]]

The polarization sum is \(\(|\)\(Rzx\)\( | \^2\)\)+|Rzy\( | \^2\); this is now to be integrated over angles.

polsum  =  Rzx Rzxcc  +  Rzy Rzycc

phiint =  Integrate[polsum, {ϕ, 0, 2 Pi}]

angint  =  
      Integrate[Sin[θ] phiint, {θ, 0, Pi}]

This result can be simplified by eliminating Qzz. The resulting contribution is

angint = 
      FullSimplify[angint /.  Qzz ->  -Qxx - Qyy]

The spherical components of the quadrupole tensor are given by the equations

eqns  =  {Q0 == -(Qxx + Qyy)/2, 
        Q1 == -(1/Sqrt[6]) (Qxz + I Qyz), 
        Q1m == (1/Sqrt[6]) (Qxz - I Qyz) , 
        Q2 == (1/Sqrt[24]) (Qxx - Qyy +  2 I Qxy), 
        Qm2 == (1/Sqrt[24]) (Qxx - Qyy -  
                2 I Qxy)}

We can obtain the quadrupole tensor components  Qij in terms spherical basis components (Subscript[Q, Λ]) by solving the above

sol   =  Solve[eqns, {Qxz, Qyz, Qxy, Qxx, Qyy}]

Finally, we can express the angular integrated polarization sum in a spherical basis as

angint0  =  FullSimplify[angint /.  sol] // First

Clear[Q0, Q1, Q1m, Q2, Q2m, Qxx, Qyy, Qzz, Qxy, Qxz, Qyz]