Physics 70006  Electrodynamics:
Homework assignment #10  due Apr. 26

Prob 5.15

Clear["`*"]

Shielded Bifilar circuit:

part (a)

Let me apologize for my earlier "hint", in which I gave an incorrect expression for the scalar potential of a wire.  As pointed out by a student in class on Wednesday, the correct expression is obtained as follows:

We know that the magnetic field H of a wire located at the origin and carrying current ii  in the + z direction is (Subscript[H, ϕ]) = (ii/(2 π ρ)), where ρ is the radial coordinate in cylindtical coordinates measured from the wire.  The scalar potential satisfies  (1/ρ)(∂_ϕ) (Subscript[Φ, M])  =  -(Subscript[H, ϕ]) = -(ii/(2 π ρ)). From this, it follows that (Subscript[Φ, M]) =  -(ii/(2 π ))ϕ, where ϕ is the azimuthal angle. We measure this  angle counterclockwise from an origin centered on the wire.  For a wire located at (x,y) = (d/2,0), the angle is  ϕ = (tan^(-1))((y/(x - d/2))). The potential for the two wires is, therefore, 
(Subscript[Φ, M]) =  -(ii/(2 π )) (ϕ[d/2] - ϕ[-d/2] ) = -(ii/(2 π ))( (tan^(-1))((y/(x - d/2))) -  (tan^(-1))((y/(x + d/2)))).  Let's proceed to expand this potential in powers of d:

ΦM  :=  -(ii/(2  π)) (ArcTan[ρ Sin[ϕ]/(ρ Cos[ϕ]  - d/2)] - 
            ArcTan[ρ Sin[ϕ]/(ρ Cos[ϕ]  + 
                      d/2)] )

Make the small d approximation.

Φapp  =  
      FullSimplify[Normal[Series[ΦM, {d, 0, 2}]]]

part (b)

Introduce a cylindrical shield and solve the resulting  BV problem:

Let κ = -(ii/(2  π))in the equal. Given that the "driving" term from part (a) has Sin[ϕ] symmetry, we may assume that the magnetic scaled potential  has the general analytic form (Subscript[ϕ, m])  = (A ρ+ B/ρ) Sin[ϕ]. Thus,
ϕin    = (α ρ+ κ/ρ) Sin[ϕ]   ρ < a
ϕmid  = (β ρ+ γ/ρ) Sin[ϕ]  a < ρ <b
ϕout   =  δ/ρ Sin[ϕ]           b < ρ
Let us set up the boundary conditions at ρ=a and b and solve for the coefficients {α,β,γ,δ}.

eqs  := {κ/a^2  +  α  ==  β + γ/
              a^2,  κ/
              a^2 - α  ==  μ (-β + γ/
                  a^2),  β + γ/b^2 == δ/
            b^2,  μ (-β + γ/b^2)  ==  δ/
            b^2}

vars :=  {α, β, γ, δ}

sol  :=  Solve[eqs, vars] // First

A1 :=  FullSimplify[α /.  sol]

B1 :=  FullSimplify[β /.  sol]

C1 :=   FullSimplify[γ /.  sol]

D1 :=   FullSimplify[δ /.  sol]

Set up the potential in the three regions

ϕin  =  (A1 ρ + κ/ρ) Sin[ϕ]

ϕmid  =  (B1 ρ + C1/ρ) Sin[ϕ]

ϕout  =  (D1/ρ) Sin[ϕ]

Find the shielding factor

F =  D1

Part (c)

Find an approximate formula for small t = (b-a) and large μ

Fapp  =  Normal[Series[D1, {μ, Infinity, 1}]]

Fapp  =  Fapp  /.  a ->  b - t

Fapp =  Normal[Series[Fapp, {t, 0, 1}]]

Fapp = Fapp[[2]]

Fapp  /.  {μ ->  200, b ->  1.25,  
        t ->  0.3}

Prob 5.24

Clear["`*"]

Mixed BV problem for a hole of radius a in a conducting plane.

Preliminary setup.   Illustrate solution to integral equation

Evaluate some special cases of  discontinuous integrals:

I1 = (∫_0^∞) (Subscript[j, 1])(
            ka) (Subscript[J, 1])(kρ) dk    &    I2 = \(TraditionalForm\`∫\_0\%\(\(∞\)\(\ \)\)k\ \(\(j\_1\)(ka)\)\ \(\(J\_1\)(kρ)\) dk\)  

Note that (Subscript[j, 1])(z) = (Sqrt[(π/(2 z))])(Subscript[J, 3/2])(z)

I1 = {Integrate[Sqrt[Pi/(2*k*a)]*BesselJ[3/2, k*a]*BesselJ[1, k*ρ], 
    {k, 0, Infinity}, Assumptions -> {ρ > 0, a > ρ}], 
   Integrate[Sqrt[Pi/(2*k*a)]*BesselJ[3/2, k*a]*BesselJ[1, k*ρ], 
    {k, 0, Infinity}, Assumptions -> {a > 0, ρ > a}]}

I2 = {Integrate[Sqrt[(k*Pi)/(2*a)]*BesselJ[3/2, k*a]*BesselJ[1, k*ρ], 
    {k, 0, Infinity}, Assumptions -> {ρ > 0, a > ρ}], 
   Integrate[Sqrt[(k*Pi)/(2*a)]*BesselJ[3/2, k*a]*BesselJ[1, k*ρ], 
    {k, 0, Infinity}, Assumptions -> {a > 0, ρ > a}]}

Here is the magnetic scalar potential on the surface ( a factor Sin[ϕ] is omitted)

Φm  =  
      Simplify[(2 (Subscript[H, 0]) a^2/π) Piecewise[{{I1[[1]], ρ < 
                  a}, {I1[[2]], ρ > a}}]]

Here is the normal component of H on the surface z=0.

Hn  =   Simplify[(2 (Subscript[H, 0]) a^2/π) Piecewise[{{I2[[1]], ρ < a}, {I2[[2]], ρ > a}}]]

Plot the result for a=1.

\(Plot[{Φm /. \ {H\_0 -> \ 1, a -> \ 1}, 
        Hn /. \ {H\_0 -> \ 1, 
            a -> \ 1}}, 
{ρ, 0, 2}, 
      PlotRange -> \ {0, 2}, 
      PlotStyle -> \ {{Thickness[0.01], Hue[0.95]}, {Thickness[0.01], 
            Hue[0.6]}}, 
      TextStyle -> {FontFamily -> "Times", 
          FontSize -> 12}, 
      Ticks -> {{0, 0.25, 0.5, 0.75, 1, 1.25, 1.5, 1.75, 2}, {0, 0.5, 1, 
            1.5, 2}}, 
PlotLabel -> \ "Φm (red)  &  Hn  (blue)"]\)

Examine the potential asymptotically (let "a" be small!)  (Subscript[j, 1])(ka)  = (1/3) ka

Φm  =  (2  a^2 (Subscript[H, 0])/π) (a/3) 
        Integrate[ 
          k  BesselJ[1, k ρ] Exp[-k z] , {k, 0, Infinity}, 
          Assumptions ->  {z > 0, ρ  ∈  
                Reals}]

Φm  =  
      Simplify[Φm Sin[ϕ]  /.  {z^2 + ρ^2 ->  
              r^2, ρ -> r Sin[θ] }, 
        Assumptions ->  r > 0]

This is the potential of a dipole that is centered on the hole and directed along the y-axis with moment   
m = ((8  (a^3))/3)(Subscript[H, 0])

Solution to Rob 5.24

Determine the potential for z=0 in the region ρ>a.

ϕout  =  (2  a^2 (Subscript[H, 0])/π) Integrate[ 
          Sqrt[ π/(2 k a)] BesselJ[3/2, k a] BesselJ[1, 
              k ρ] , {k, 0, Infinity}, 
          Assumptions ->  {a  > 0,  ρ >  a} ]

Find and simplify the cartesian components of the field:

Hρ =  -D[ϕout, ρ] Sin[ϕ]

Hϕ  =  -ϕout Cos[ϕ]/ρ

Hx  =  
      Simplify[Cos[ϕ] Hρ - Sin[ϕ] Hϕ] /.  
        Sin[2  ϕ] ->  2 x y/ρ^2

Hy  = 
      Expand[Sin[ϕ] Hρ + 
            Cos[ϕ] Hϕ] /.  {Sin[ϕ] ->  y/ρ, 
          Cos[ϕ] ->  x/ρ}

Hy  =  Expand[Hy  /.  x^2  ->  ρ^2 - y^2]

Hyy  =  Simplify[Coefficient[Hy, y^2]]

Hy0 =  Expand[Hy -  Coefficient[Hy, y^2] y^2]

Hy  =  Hy0 + Hyy y^2

Determine the currents on the upper surface. The components of the current are 
(Kx, Ky) = (-Hy-H0, Hx)

Kx  =  
      FullSimplify[-(Subscript[H, 0]) - Hy  /.  {(Subscript[H, 0]) ->  1,  
            a -> 1,  ρ ->  Sqrt[x^2 + y^2]}]

Ky  =  
      Simplify[Hx  /.  {(Subscript[H, 0]) ->  1,  
            a -> 1,  ρ ->  Sqrt[x^2 + y^2]}]

Kxx =  Piecewise[{{0, x^2 + y^2 < 1}, {Kx, x^2 + y^2 > 1}}]

Kyy =  Piecewise[{{0, x^2 + y^2 < 1}, {Ky, x^2 + y^2 > 1}}]

Plot the currents

<< Graphics`PlotField`

ff  =  
      PlotVectorField[{Kxx, Kyy}, {x, -1.5, 1.5}, {y, -1.5, 1.5}, 
        PlotPoints ->  10, ColorFunction ->  Hue, 
        DisplayFunction ->  Identity]

c1  =  Graphics[{Thickness[0.008], Circle[{0, 0}, 1]}]

Kup =  
      Show[ff, c1, DisplayFunction ->  $DisplayFunction]

Owing to the fact that the signs of Hx and Hy are changed on the lower surface and that (Subscript[H, 0]) vanishes, the current flow on the lower surface is (Klx, Kly) = (-Hy, Hx).

Klx  =  
      FullSimplify[-Hy  /.  {(Subscript[H, 0]) ->  1,  
            a -> 1,  ρ ->  Sqrt[x^2 + y^2]}]

Kly  = Ky

Klxx =  
      Piecewise[{{0, x^2 + y^2 < 1}, {Klx, x^2 + y^2 > 1}}]

Klyy =  
      Piecewise[{{0, x^2 + y^2 < 1}, {Kly, x^2 + y^2 > 1}}]

gg  =  
      PlotVectorField[{Klxx, Klyy}, {x, -1.5, 1.5}, {y, -1.5, 1.5}, 
        PlotPoints ->  10, ColorFunction ->  Hue, 
        DisplayFunction ->  Identity]

Klo  =  
      Show[{gg, c1}, DisplayFunction ->  $DisplayFunction]

Prob 5.25

Clear["`*"]

Interaction energy of a long wire with a rectangular or circular loop.

part (a)

A wire carrying current (Subscript[I, 2 ])runs parallel to y and  is located at (x,z) = d ( Cos[α], Sin[α] ).  
A rectangular loop with sides a and b is in the (xy) plane centered at the origin. The sides of length a are parallel to the y axis and those of length b are parallel to the x axis. The loop carries current (Subscript[I, 1]). The current in the side of the loop that is located at x=b/2 runs in the same direction as (Subscript[I, 2]). Determine the interaction energy (Subscript[W, 12]) and the force exerted on the loop by the wire.

Express (Subscript[W, 12]) = (Subscript[I, 1]) ∫A  .  dl = (Subscript[I, 2])a [ (Subscript[A, y])(b/2, 0)-(Subscript[A, y])(-b/2,0)]

Ay[x_, 
        z_]  =  - ((Subscript[I, 2]) (Subscript[μ, 0]))/(4 π) Log[(x -  
                  d Cos[α])^2 + (z - 
                  d Sin[α])^2]

W12  =  (Subscript[I, 1]) a (Ay[b/2, 0] - Ay[-b/2, 0])

The force on the  circuit  (method 1)

Fd  =  -Simplify[D[W12, d]]

Fa  =  -Simplify[D[W12, α]/d]

Fxx  =  Simplify[Fd Cos[α] -  Fa Sin[α]]

Fzz  =  Simplify[Fd Sin[α] +  Fa Cos[α]]

Examine some limits: α= 0 or α = π/2.

FullSimplify[{Fxx, Fzz} /.  α ->  0]

FullSimplify[{Fxx, Fzz} /.  α ->  π/2]

One can easily verify the correctness of these results.

Here is an alternative direct calculation of the force using F = (Subscript[I, 1]) ∫[dl x B]

Bz  =  D[Ay[x, z], x] /.  z -> 0

Bx  =  -D[Ay[x, z], z] /.  z -> 0

Fx  =  (Subscript[I, 1]) 
        a Simplify[( 
              Bz /.  {x ->  b/2})  -  (Bz /. { 
                  x ->  -b/2})]

Fz  =  -(Subscript[I, 1]) a Simplify[( 
              Bx /.  {x ->  b/2})  -  (Bx /. { 
                  x ->  -b/2})]

Circle: Energy calculation by Two methods

Method 1)    (Subscript[W, 12]) = (Subscript[I, 1])\(TraditionalForm\`\(\(\ \)\(\((Flux)\)\ \  = \ 
        I\_\(\(1\)\(\ \)\)\ \(∫\_0\%a\ ρ\ dρ\ \(∫\_0\%\(2  π\)\ \ \ dϕ\ \ B\_z[ρ\ Cos[ϕ]\ , 0]\)\)\)\)\)

Evaluate (Subscript[B, z])(x,z)

Bz  =  D[Ay[x, z], x]

Evaluate (Subscript[B, n])=(Subscript[B, z])(ρ Cos[ϕ],0)

Bn  =  
      Bz /.  {x ->  ρ Cos[ϕ] , z -> 0}

Nt  =  10

Expand (Subscript[B, n])  in an asymptotic series in d.

Bn  =  
      Expand[Simplify[Normal[Series[Bn, {d, Infinity, Nt}]]]]

(Subscript[W, 12])  =  
      (Subscript[I, 1]) Integrate[ ρ Integrate[
              Bn, {ϕ, 0, 2  π}], {ρ, 0, a}]

Simplify this result

(Subscript[W, 12])  =  ((Subscript[I, 1]) (Subscript[I, 2]) (Subscript[μ, 0]) a) Expand[
          (Subscript[W, 12])/( (Subscript[I, 1]) (Subscript[I, 2]) (Subscript[μ, 0]) a)]

Here is an interesting comparison:  (1 - (Sqrt[1 - (z^2)]))/z   =  (z/2) + ((z^3)/8) + 
          ((z^5)/16) + ((5 (z^7))/128) + ((7 (z^9))/256). 
It follows that the term in  (..) above is  Re{(1 - (Sqrt[1 - (z^2)]))/z}   with z = a (e^(i α))/d.

S[u_] =  Normal[Series[1 - Sqrt[1 - u^2], {u, 0, Nt}]/u]

Here is  the real part of   Re{(1 - (Sqrt[1 - (z^2)]))/z}   with z = a (e^(i α))/d  for comparison

Sreal  =  
      Expand[(ExpToTrig[S[a Exp[I α]/d]] + 
              ExpToTrig[S[a Exp[-I α]/d]])/2]

As an alternative, we may evaluate the interaction energy as (Subscript[W, 12])= (Subscript[I, 1])a (∫_0^(2  π)) 
          Cos[ϕ] (Subscript[A, y])(a Cos[ϕ], 
              0) dϕ

Ayy  =  Ay[a Cos[ϕ], 0]

Expand Ay in a series

Nt  =  10

Aexp  =  
      Expand[Simplify[Normal[Series[Ayy, {d, Infinity, Nt}]]]]

(Subscript[W, 12]) = 
      (Subscript[I, 1]) a Integrate[Cos[ϕ] Aexp, {ϕ, 0, 2 π}]

Simplify this result

(Subscript[W, 12])  =  ((Subscript[I, 1]) (Subscript[I, 2]) (Subscript[μ, 0]) a) Expand[(Subscript[W, 12])/( (Subscript[I, 1]) (Subscript[I, 2]) (Subscript[μ, 0]) a)]

Note that both methods give the same result, which can be rewritten: 
W= (Subscript[μ, 0]) (Subscript[I, 1])(Subscript[I, 2]) a Re{(1 - (Sqrt[1 - (z^2)]))/z}   with z = a (e^(i α))/d.

Force on circular circuit

Direct calculation:

Bz =  
      D[Ay[x, z], x] /.  {x ->  a Cos[ϕ], 
          z ->  0}

Bx =  -D[Ay[x, z], z] /.  {x ->  a Cos[ϕ], 
          z ->  0}

Expand in a series

Nt  =  10

Bxa  :=  Simplify[Normal[Series[Bx, {d, Infinity, Nt}]]]

Bza  :=  Simplify[Normal[Series[Bz, {d, Infinity, Nt}]]]

Fx =  (Subscript[I, 1]) 
        a Integrate[Cos[ϕ] Bza, {ϕ, 0, 2  π}]

Fz =  -(Subscript[I, 1]) 
        a Integrate[Cos[ϕ] Bxa, {ϕ, 0, 2  π}]

Simplify the above:

Fzs  =   (Subscript[I, 1]) (Subscript[I, 2]) (Subscript[μ, 0]) Expand[
          Fz/( (Subscript[I, 1]) (Subscript[I, 2]) (Subscript[μ, 0]))]

Fxs  =   (Subscript[I, 1]) (Subscript[I, 2]) (Subscript[μ, 0]) Expand[
          Fx/( (Subscript[I, 1]) (Subscript[I, 2]) (Subscript[μ, 0]))]

Normal[Series[{1/Sqrt[1 - z^2] - 1}, {z, 0, Nt}]]

Alternative:

Fd  =  (Subscript[I, 1]) (Subscript[I, 2]) (Subscript[μ, 0]) 
        Expand[-D[(Subscript[W, 12]), 
                d]/( (Subscript[I, 1]) (Subscript[I, 2]) (Subscript[μ, 0]))]

Fa  =   (Subscript[I, 1]) (Subscript[I, 2]) (Subscript[μ, 0]) 
        Expand[-D[
                (Subscript[W, 12])/d, α]/( (Subscript[I, 1]) (Subscript[I, 2]) (Subscript[μ, 0]))]

Fxx  =  Simplify[Fd Cos[α] -  Fa Sin[α]]

Fxx  =  
      Expand[Fxx/((Subscript[I, 1]) (Subscript[I, 2]) (Subscript[μ, 0]))] (Subscript[I, 1]) (Subscript[I, 2]) (Subscript[μ, 0])

Fzz  =  
      Expand[Simplify[Fd Sin[α] +  Fa Cos[α]]]

c1  = 
      Sum[Coefficient[
            Expand[Fzz/((Subscript[I, 1]) (Subscript[I, 2]) (Subscript[μ, 0]))], (a/d)^(2  
                  k)] (a/d)^(2  k), {k, 1, 5}]

Fzz  =  
      (Subscript[I, 1]) (Subscript[I, 2]) (Subscript[μ, 0]) (c1[[1]] + 
            Sum[Simplify[Coefficient[c1, (a/d)^k]] (a/d)^k, {k, 4, 
                10, 2}])

Fxs  ==  Fxx

Fzs  ==  Fzz

Prob 5.34

Interaction between two circular loops

Clear["`*"]

parts (a & b)

The expression for the mutual inductance of two identical co-axial rings of radius a separated by distance R is
(Subscript[M, 12]) = ((Subscript[μ, 0])\(TraditionalForm\`\(\(πa\^2\)\()\)\)\ \(e\^\(-kR\)\) dk\).  We are required to develop an asymptotic series for (Subscript[M, 12]).  For this purpose, we expand (([(Subscript[J, 1])(ka)])^2)in a Taylor series.

Nt  =  8

Ser[k_] =   Normal[Series[BesselJ[1, k a]^2, {a, 0, 8}]]

Integrate the series expression:

M12  =  ((Subscript[μ, 0 ]) π a/2) Expand[
          2 a Integrate[Ser[k]  E^(-k R), {k, 0, Infinity}, 
              Assumptions ->  R > 0]]

The above expression agrees with that given in Jackson.

part (c)

Obtain an expression for the mutual inductance of two co-planar rings. For this purpose, we start with a scalar potential for B of the ring centered at the origin. (For simplicity, we omit a factor (Subscript[μ, 0])(Subscript[I, 1])/2 everywhere below)

Φm  =  (1 - z/Sqrt[a^2 + z^2])

Baxis  =  -Simplify[D[Φm, z]]

Obtain an asymptotic series for Φm

Nt = 10

Φser  =  
      Normal[Series[Φm, {z, Infinity, Nt}]]

Analytically continue the series

t  =  
      Table[Coefficient[Φser, z^(-k)], {k, 2, Nt, 
          2}]

Φser  =  
      Sum[t[[k]] LegendreP[2  k - 1, μ]/r^(2  k), {k, 1, 
          Nt/2}]

Now find the field (Subscript[B, z]) in the plane (μ=0).  Note :    (Subscript[B, z]) = -(Subscript[B, θ]) = + (1/r)∂Φ/∂θ = -(1/r)∂Φ/∂μ

Bz[r_]  =  -Expand[
            D[Φser, μ]/r ] /.  μ -> 0

Introduce coordinates radial and angular coordinates  ρ and ξ  relative to center of second loop.

Bzrel  =  
      Bz[Sqrt[R^2 + ρ^2 + 2 ρ R Cos[ξ]]]

Bzrel =  Normal[Series[Bzrel, {R, Infinity, 10}]]

Evaluate the Flux through the second loop (introduce a - sign since flux is downward)

Flux  =  -Integrate[ ρ Integrate[
              Bzrel, {ξ, 0, 2 π}], {ρ, 0, a}]

Now use relation Flux = (Subscript[M, 21])(Subscript[I, 1]) to determine (Subscript[M, 21]) (resupply omitted factor)

Flux  =  ((Subscript[μ, 0]) (Subscript[I, 1]) a π)/4  Expand[
          2 Flux/(a π)]

Factoring (Subscript[I, 1])leads to a result that agrees with the expression for (Subscript[M, 12 ])in the text.

Part (d)

Method (1)  Look at forces in the co-planar case by direct calculation

Fx1  =  
      Expand[a Integrate[
              Cos[ξ] Bzrel, {ξ, 0, 2 π}] /.  ρ ->  
            a]

Fy1 = Expand[Integrate[Sin[ξ]Bzrel, {ξ, 0, 2 π}] /. ρ -> a]

Reintroduce omitted factors ((Subscript[I, 1])(Subscript[I, 2])(Subscript[μ, 0]))/2

Fx1  =  ((Subscript[μ, 0]) (Subscript[I, 1]) (Subscript[I, 2]) /2)  Fx1

The force on co-planar loops is repulsive and directed along line of centers.

Now, consider co-axial case

Br :=  -D[Φser, r] /.  {r ->  
            Sqrt[R^2 + a^2],  μ ->  R/Sqrt[R^2 + a^2]}

Bθ :=  
      D[Φser, μ] a/r^2  /.   {r ->  
            Sqrt[R^2 + a^2],  μ ->  R/Sqrt[R^2 + a^2]}

Fz  :=  -R/Sqrt[R^2 + a^2] Bθ  -  
        a/Sqrt[R^2 + a^2] Br

Fz =  Normal[Series[Fz, {R, Infinity, 10}]]

Reintroduce omitted factors ((Subscript[I, 1])(Subscript[I, 2]) 2π a (Subscript[μ, 0]))/2

Fz  =  ((Subscript[μ, 0 ]) (Subscript[I, 1])/2) 
        (Subscript[I, 2]) (2 π a) Fz

The force on co-axial loops is attractive and directed along line of centers.