Physics 70006  E&M I

Generalized Legendre Functions

Conical Harmonics

Clear["`*"]

P[ν, θ] is a generalized Legendre function. We want to force it to be a conical harmonic associated with opening half-angle β.

P[ν_, θ_]  =  
      Hypergeometric2F1[-ν, ν + 1, 
        1, (Sin[θ/2])^2]

Let's consider a cone of opening half-angle β = π/6 (30°).  Our first goal is to estimate values (Subscript[ν, k]) that put the 1st,  2nd, 3rd, ... zero of P at  β = π/4.

β =  π/4

Plot[P[ν, β], {ν, 0, 20}, 
      PlotStyle ->  {Thickness[0.01], Hue[ .99]}, 
      AxesLabel ->  {ν, ""}, 
      TextStyle -> {FontSize -> 12}, 
      PlotLabel  ->  "P[ν,β]  vs. ν for β = \
π/4"]

From the graph, one sees that the approximate roots for this value of β are at νapp = 2.5, 6.5, 10.5, 14.5, ..v  (spacing is 4) . Now, let's obtain more precise values starting from ⋁app.

νapp  =  Table[-1.5 + 4 k, {k, 1, 7}]

FindRoot[P[ν, β] == 0, {ν, νapp}]

Assign these exact roots to rge array ν1 and check that  P[ν1, β] = 0

ν1   =  ν /.  %

P[ν1, β]

Plot the functions P[ν1[i], θ] from 0 to β. The respective functions have a zero at β and 0, 1, 2, 3, ... for θ<β.

Plot[{P[ν1[[1]], θ], 
        P[ν1[[2]], θ], P[ν1[[3]], θ], 
        P[ν1[[4]], θ], P[ν1[[5]], θ], 
        P[ν1[[6]], θ], 
        P[ν1[[7]], θ]}, {θ, 0, β}, 
      PlotStyle -> {{Hue[0], Thickness[0.008]}, {Hue[0.15], 
            Thickness[0.008]}, {Hue[0.30], Thickness[0.008]}, {Hue[0.45], 
            Thickness[0.008]}, {Hue[0.60], Thickness[0.008]}, {Hue[0.75], 
            Thickness[0.008]}, {Hue[0.90], Thickness[0.008]}}, 
      AxesLabel ->  {θ, ""}, 
      TextStyle -> {FontSize -> 12}, 
      PlotLabel  ->  "Conical Harmonics for β = \
π/4"]

Check the orthogonality of the the functions.

Table[
        NIntegrate[
          P[ν1[[i]], θ] P[ν1[[j]], θ] Sin[θ], {θ, 0, β}, AccuracyGoal ->  6], {i, 1, 7}, {j, 
          1, 7}] // TableForm

Near the vertex of the cone ν0 = ν1[1]  will dominate the series expansion for the potential

ν0  =  ν1[[1]]

Φ[r_, θ_]  =  
      r^ν0 P[ν0, θ]

Eθ  =  - (1/r) D[Φ[
            r, θ], θ]

σ[
        r_]  =  - 
          Eθ  /.  θ ->  β

Plot[Abs[σ[r]], {r, 0, 2}, 
      PlotStyle -> {Hue[0.6], Thickness[0.008]}, 
      AxesLabel  ->  {r, " "}, 
      TextStyle ->  {FontSize ->  14}, 
      PlotLabel  ->  "|σ| for a cone with β = \
π/4" ]

Potential plot

vv   =  
      Piecewise[{{Φ[
              r, θ], θ < β}, {0, θ > β}}]

v[x_, y_]  =  
      vv  /.  {r ->  Sqrt[x^2 + y^2], θ ->  
            ArcCos[y/Sqrt[x^2 + y^2]]}

Plot3D[v[x, y], {x, 10^-6, 1}, {y, 0, 1}, 
      ViewPoint ->  {1.2, 1.2, 1.2}, AspectRatio ->  Automatic, 
      AxesLabel -> {x, z, "Φ(x,z)"}, 
      Ticks ->  {Automatic, Automatic, {0, 0.5, 1}}, 
      TextStyle -> {FontSize -> 12}]

cp  =  
      ContourPlot[v[x, y], {x, 10^-6, 3}, {y, 10^-6, 3}, 
        PlotPoints ->  50, ColorFunction -> Hue, 
        ContourSmoothing ->  
          True, 
DisplayFunction ->  Identity, 
        AspectRatio ->  Automatic]

Needs["Graphics`PlotField`"]
ce  =  
      PlotGradientField[-v[x, y], {x, 10^-6, 3}, {y, 10^-6, 
          3}, 
ScaleFunction ->  (1 &),  
        DisplayFunction ->  Identity, 
        AspectRatio ->  Automatic]

Show[cp, ce, DisplayFunction ->  $DisplayFunction]