*
chapter_12_table_15

The data in Table 12.15 consist of reaction time scores for 10 young participants where 
each participant contributes 3 scores to the analysis. In particular, each participant is
exposed to each of 3 experimental conditions, angle (0, 4, and 8). For the current analyses
Table 12.15 is appended to Table 12.7, which contains reaction time scores for 10 old 
participants for angles of 0, 4, and 8. Thus, it is necessary to perform some data 
management before analyzing the data. The following SAS syntax is used to form the data set
using Tables 12.15 and 12.7 along with adding a variable to the data set corresponding to 
the age factor;

LIBNAME md 'd:\data files by type\sas data files\tables';
DATA c12t15; 
SET md.chapter_12_table_15;
PROC APPEND BASE=c12t15 
   DATA=try.chapter_12_table_7;
RUN;
DATA c12t15;
SET c12t15;
INPUT age;
CARDS; 
1 
1 
1 
1 
1 
1 
1
1
1
1
2
2
2
2
2
2
2
2
2
2
;
RUN;

* Now we move on to performing the split-plot ANOVA. The first tests of interest here are
the omnibus tests within the split-plot ANOVA. The following SAS syntax replicates the 
results shown in Table 12.19; 

PROC GLM;  
CLASS age; 
MODEL angle0 angle4 angle8 = age;
REPEATED angle 3;
RUN;

* Also, in order to illustrate how to perform tests of marginal means in the context of 
split-plot designs, we test for the quadratic trend of the angle effect, averaging over 
age. This tests corresponds to the test performed on page 600 using a separate error term. 
If one were interested in using the pooled error term approach for this test of the 
quadratic trend of angle, one could divide the mean square for the contrast associated with
the quadratic trend of angle by the mean square used as the denominator for the omnibus 
test of the angle main effect using the univariate mixed-model approach. Using the syntax 
suggested here, this pooled error term is the mean square found under the headings 
"Repeated Measures Analysis","Within", and then "Type III Model ANOVA" within the row 
entitled "Error(angle)" in the unvariate mixed-model output;

* The following SAS syntax is used to test the quadratic trend of angle averaging over age
using the separate error term approach;

PROC GLM;  
CLASS age; 
MODEL angle0 angle4 angle8 = age;
REPEATED angle 3 POLYNOMIAL /SUMMARY;
RUN;
 
* Also of interest are the simple effects for angle within specific levels of noise and the 
simple effects for noise within specific levels of angle. Specifically, the tests shown 
here are the simple effect of angle for young participants and the simple effect of age at 
angle 0. It is important to note that one could either use the separate error term or 
pooled error term approach for these tests. The following syntax produces the tests of the 
simple effect angle for young participants using the separate error term approach shown on 
page 602. Note that the young participants are coded as “2” for the age variable and thus 
the output corresponding to this value is of interest here; 

PROC GLM;  
CLASS age;
WHERE(age=2); 
MODEL angle0 angle4 angle8 = /NOUNI;
REPEATED angle 3;
RUN;

* There is no straightforward method to calculating the pooled error term for the simple 
effect of angle for young participants, other than obtaining the pooled error term from the
omnibus test output and obtaining the appropriate F ratio through hand calculations. One 
should find the results obtained from these hand calculations should agree with the F ratio 
for the pooled error term found on page 602.;

* As mentioned, we are also interested in obtaining the test of the simple effect of age at
angle 0. The following syntax produces this test as shown on page 603 using a separate 
error term; 

PROC GLM;  
CLASS age; 
MODEL angle0 = age;
RUN;

* As was the case in for the SPSS syntax, one can find the pooled error term and test in 
this particular situation by first running the analyses for the simple effects of angle 0, 
4, and 8, then taking an unweighted average of the error mean squares used for the tests of
these simple effects. One would then use this error mean square to calculate the 
appropriate F ratio. One would then need to find the critical F value (using the 
appropriate degrees of freedom) to test the observed F ratio for statisical significance. 
The result obtained should correspond to the result shown on page 602. The following syntax 
produces the tests of the simple effect of age at angle 4 and 8 in order to obtain the 
pooled error term;

* simple effect of age at angle 4;

PROC GLM;  
CLASS age; 
MODEL angle4 = age;
RUN;

* simple effect of age at angle 8;

PROC GLM;  
CLASS age; 
MODEL angle8 = age;
RUN;

* Other tests of potential interest include interaction contrasts. In particular, it may be
of interest to determine if the quadratic trend is different for young and old participants. 
As is the case for other more specific group comparisons, either a separate or a pooled 
error term could potentially be used. In fact the syntax used to obtain the test of the 
quadratic trend of angle averaging over age also yields the test of whether the quadratic 
trend is different for the old and yound participants using the separate error term. This 
test is found under "Contrast variable: angle_2" in the row denoted "age" in the output 
corresponding to the SAS syntax mentioned. If one were interested in using the pooled error 
term, then the syntax for the omnibus tests should be run, and the denominator used for the
test of the omnibus interaction test for the univariate mixed-model approach should be used
as the denominator of the interaction contrast to form the appropriate F ratio;