*
chapter_6_table_1

The data in Table 6.1 consist of recall scores for 24 children who have been randomly 
assigned to one of four experimental conditions where there are 6 children in each 
condition. The experimental conditions of interest are 1, 2, 3, and 4 minutes where the
number of minutes is the amount of time the child is allotted to study a list of words 
before attempting to recall the words. The dependent variable (i.e., the recall scores) are
the number of words the child is able to recall after a brief interference task;  

LIBNAME md 'd:\data files by type\sas data files\tables';
DATA c6t1; 
SET md.chapter_6_table_1;

*The first hypothesis of interest is whether the number of words recalled is linearly 
related to the number of minutes spent studying. We test this hypothesis by determining if 
the linear trend is statistically significant. Pages 252 and 253 are associated with this 
test. The following SAS syntax is used to obtain the test of the linear trend along with the
estimate of the slope parameter from the data in Chapter 6, Table 1. Keep in mind that in 
order to obtain the correct slope estimate, one must divide by the sum of the squared 
weights as shown page 248. This is why weights of -.3, -.1, .1, and .3 are used to estimate 
the linear trend;

PROC GLM; 
CLASS minutes; 
MODEL recall = minutes;
CONTRAST 'linear' minutes -1.5 -.5 .5 1.5;
ESTIMATE 'linear' minutes -0.3 -0.1 0.1 0.3;
RUN;

*Next, we are interested in determining if there is any nonlinearity (i.e., deviation from
linearity) present in the relationship between the number of words recalled and the amount 
of time spent studying. Page 257 demonstrates the results associated with this statistical 
test. The following SAS syntax is used to obtain the test of nonlinearity from the data in 
Chapter 6, Table 1;

PROC GLM; 
CLASS minutes; 
MODEL recall = minutes;
CONTRAST 'non-linear' minutes 1 -1 -1 1, minutes -1 3 -3 1;
RUN;

*Finally, we are interested in determining if the quadratic or cubic components of the 
relationship between the number of words recalled and the amount of time spent studying are 
statistically significant. It is important to note that the results for the linear, 
deviation from linear, quadratic, and cubic trends replicated by the procedures shown here 
are illustrated in Table 6.3. The following SAS syntax is used to obtain the test of the 
quadratic and cubic trends from the data in Chapter 6, Table 1;

PROC GLM; 
CLASS minutes; 
MODEL recall = minutes;
CONTRAST 'quadratic' minutes 1 -1 -1 1; 
CONTRAST 'cubic' minutes -1 3 -3 1;
RUN;