*This SAS IML Program is for the 1000 population conditions with 21 parameters 
for the mediation model with 9 indicators used in Yuan, Zhang, and Wang 2024;
options linesize=215 nodate nonumber;
title;;
proc iml;
reset noname;

*----------------------------------;
start cond_popu(N_c,p_x,p_y1,p_y2,seed,Cond_Nc);
p=p_x+p_y1+p_y2;
q=2*p+3;
Cond_Nc=j(N_c,q,0); *Nc sets of conditions of population (21 parameters);

do i=1 to N_c;
	z_x=uniform(j(p_x,1,seed));
	z_y1=uniform(j(p_y1-1,1,seed));
	z_y2=uniform(j(p_y2-1,1,seed));
	z_g=uniform(j(2,1,seed)); *(a,c);
	z_b=uniform(seed); *b;
	z_zeta=uniform(j(2,1,seed));
	z_ex=uniform(j(p_x,1,seed));
	z_ey1=uniform(j(p_y1,1,seed));
	z_ey2=uniform(j(p_y2,1,seed));

	lamb_x=j(p_x,1,.2)+z_x;
	lamb_y1=1//(j(p_y1-1,1,.2)+z_y1);
	lamb_y2=1//(j(p_y2-1,1,.2)+z_y2);
	gamma=j(2,1,.2)+z_g;
	beta=.2+z_b;
	sig2_zeta=j(2,1,.2)+z_zeta;
	psi_x=j(p_x,1,.2)+z_ex;
	psi_y1=j(p_y1,1,.2)+z_ey1;
	psi_y2=j(p_y2,1,.2)+z_ey2;

	theta0=lamb_x//lamb_y1[2:p_y1]//lamb_y2[2:p_y2]//gamma//beta//sig2_zeta//psi_x//psi_y1//psi_y2;
	Cond_Nc[i,]=theta0`;
end;
finish;
*---------------------------------------------------;
*The numbers of indiucators for the three latent variables;
p_x=3;
p_y1=3;
p_y2=3;
p_y=p_y1+p_y2;
p=p_x+p_y;
ep=.00001;

seed=1111111111; *control the population values of the N_c conditions;

N_c=1000;

run cond_popu(N_c,p_x,p_y1,p_y2,seed,Cond_Nc);
print "The 1000 population conditions with 21 parameters for the mediation model with 
9 indicators used in Yuan, Zhang, and Wang 2024";
print Cond_Nc;