#!/bin/csh -f

set DIR = /afs/nd.edu/courses/math/math211.01

cat $DIR/NEWS

echo 'To submit an assignment,'
echo 'you should be in the directory that CONTAINS the files to submit'

#set CMD = $0; set CMD = $CMD:t

set done = 0
while (! $done)
  echo -n 'Enter assignment number (0 1,2,3,4,5,6,7,8, or 9): '
  set number = "$<"
  if ($number  == '') exit (-1)
  if ($number >= 0 && $number <= 9) then
    set done = 1
    if !( -f $DIR/homeworks/homework$number) then
       echo "homework$number has not been assigned yet."
       exit(-1)
    endif
    if !( -d $DIR/assignments/$USER/assignment$number ) then
       echo "Directory $DIR/assignments/$USER/assignment$number not found"
       exit(-1)
    endif
    set ACL=`fs listacl $DIR/assignments/$USER/assignment$number|grep $USER`
    if ( $ACL[$#ACL] == 'rl' ) then
       set DUE = (`grep DUE $DIR/homeworks/homework$number`)
       shift DUE
       echo "the homework submission directory has been locked"
       echo "the deadline is 24:00 midnight on $DUE"
       exit(-1)
    endif
    set ASSIGN = (`grep FILES $DIR/homeworks/homework$number`)
    shift ASSIGN
  endif
end

foreach file ($ASSIGN)
  if (-f $file) then
      echo -n "Does $file compile? (y/n) "
      set FLAG = "$<"
      if ( $FLAG == 'y') then
         /bin/cp $file $DIR/assignments/$USER/assignment$number
         echo "$file copied"
      else
         echo "$file not copied"
      endif
  else
      echo "$file not found"
  endif
end