version 12.1
*** Imputation for a single continuous variable using regress
webuse mheart0, clear
sum
mi set mlong
mi register imputed bmi
mi register regular attack smokes age hsgrad female
mi impute regress bmi attack smokes age hsgrad female, add(20) rseed(2232)
list bmi attack smokes age hsgrad female _mi_id _mi_miss _mi_m if  _mi_id ==8
mi xeq 0 1 20: summarize bmi
mi estimate, dots: logit attack smokes age bmi hsgrad female
mi xeq 0: logit attack smokes age bmi hsgrad female, nolog
mi describe

*** Appendix A: More examples
* PMM - Predictive Mean Matching
webuse mheart0, clear
mi set mlong
mi register imputed bmi
mi impute pmm bmi attack smokes age hsgrad female, add(20) knn(5) rseed(2232)
mi estimate: logit attack smokes age bmi hsgrad female

* Logit
webuse mheart2, clear
mi set mlong
* This will show us how much missing data, and the ranges of observed values
mi misstable summarize
mi register imputed hsgrad
mi impute logit hsgrad attack smokes age bmi female, add(10) rseed(2232)
* Estimates before imputation
mi xeq 0: logit attack smokes age bmi female hsgrad
* Estimates after imputation
mi estimate: logit attack smokes age bmi female hsgrad

* Multinomial Logit
webuse mheart3, clear
mi set mlong
mi misstable summarize
mi register imputed marstatus
mi impute mlogit marstatus attack smokes age bmi female hsgrad, add(20) rseed(2232)
* Estimates before imputation
mi xeq 0: logit attack smokes age bmi female hsgrad i.marstatus
* Estimates after imputation
mi estimate: logit attack smokes age bmi female hsgrad i.marstatus

*** Appendix B: More than 1 variable
webuse mheart8s0, clear
mi describe
mi misstable patterns, frequency
mi impute chained (regress) bmi age = attack smokes hsgrad female, add(20) rseed(2232)
mi xeq 0: logit attack smokes age bmi hsgrad female, nolog
mi estimate: logit attack smokes age bmi hsgrad female