version 13.1
use https://www3.nd.edu/~rwilliam/statafiles/shuttle2.dta, clear
* Date has been added to shuttle2.dta, but here is the command that created it.
* gen date = mdy( month, day, year)
ologit distress date temp
* Compute the Z value
predict z, xb
* Get the predicted probabilities for each of the three possible outcomes.
* Specify one var for each outcome
predict none onetwo threeplus, p
list flight temp date distress z none onetwo threeplus
* Brant test
brant, detail
* gologit2 LR test (also BIC and AIC)
quietly gologit2 distress date temp, npl sto(gologit)
quietly gologit2 distress date temp, pl sto(ologit)
lrtest gologit ologit, stats
* gologit2 Wald test (with non-svy data)
use https://www3.nd.edu/~rwilliam/statafiles/shuttle2.dta, clear
quietly gologit2 distress date temp
test [#1 = #2]
* Omodel test
use https://www3.nd.edu/~rwilliam/statafiles/shuttle2.dta, clear
omodel logit  distress date temp
* oparallel tests, including BIC
quietly ologit distress date temp
oparallel, ic
* Artificial example of mimrgns and ologit
version 14.2
webuse mheart1s20, clear
generate health = 4 - irecode(age, 45, 55 , 65)
label define health 1 "poor" 2 "fair" 3 "good" 4 "excellent"
label values health health
tab1 health
mi estimate: ologit health i.attack i.smokes bmi
* Adjusted predictions for attack
mimrgns attack, predict(default)
* AMES for attack
mimrgns, predict(default) dydx(attack)
* gologit2 Wald test (with svy data)
webuse nhanes2f, clear
quietly svy: gologit2 health weight i.female age i.race, npl
test [#1 = #2 = #3 = #4]