version 13.1
* svy command -- note that many commands deliberately produce
* fatal errors, Also ftest must be installed from SSC

* The svy and svyset commands
webuse nhanes2f, clear
svyset
sum finalwgt stratid psuid
reg weight height age i.female i.black
svy: reg weight height age i.female i.black

* Subsample analyses
svy, subpop(if female==0): reg weight height age i.black

* Commands that don't work & their alternatives
webuse nhanes2f, clear
svy: summarize diabetes black weight height
svy: mean diabetes black weight height
sw, pe(.05): svy: logit diabetes black weight height

* svy post-estimation commands
webuse nhanes2f, clear
svy: mean female black height weight diabetes
estat sd

* OLS tests that do and do not work
svy: reg weight height age
est store m1
svy: reg weight height age i.female i.black
est store m2
test 1.female 1.black
ftest m1 m2
nestreg, quietly: svy: reg weight (height age) (female black)

* OLS post-estimation that does not work
quietly svy: reg weight height age female black
dfbeta
estat hetttest
estat imtest
rvfplot
estat lvr2plot

* CDA models -- What works and what does not
webuse nhanes2f, clear
* Constrained model
svy: logit diabetes female black
est store m1
svy: logit diabetes female black weight height
est store m2
lrtest m1 m2, all
* Use Wald test instead
test weight height