* 1. Basic svy problem
version 13.1
use https://www3.nd.edu/~rwilliam/statafiles/anes_codeddata, clear 
* Describe the vars that will be used
des pres2008 female race age
*Svy set the data
svyset CASEID [pweight = V080102A]
*Descriptive stats- First do the continous var
mean age
estat sd
svy: mean age
estat sd
* Now do the categorical variables. 
proportion race female
svy: proportion pres2008 race female
*Logistic Regression & Margins With and Without Svy;
logit pres2008 i.female i.race age, nolog
margins female
svy: logit pres2008 i.female i.race age
margins female

* 2. Basic MI problem
version 13.1
use https://www3.nd.edu/~rwilliam/statafiles/mdpov2.dta, clear
sum pov age mother spouse hours
mi set mlong
mi misstable summarize
mi misstable patterns
mi register imputed age mother
mi impute chained (regress) age (logit) mother = pov spouse hours, add(20) rseed(2232)
mi xeq 0: logit pov age i.mother i.spouse hours, nolog
mi estimate, dots: logit pov age i.mother i.spouse hours
mimrgns spouse, predict(pr)