version 16
use https://www3.nd.edu/~rwilliam/statafiles/Obama2008, clear

* American National Election Study (ANES) 2008 Time Series Study
* Only necessary variables for this analysis are included in the extract.
* Complete dataset and documentation can be obtained from 
* https://electionstudies.org/data-center/2008-time-series-study/
* ANES gave permission for us to circulate an extract using its data.

* ICPSR has a slightly different version of the data at
* https://www.icpsr.umich.edu/web/ICPSR/studies/25383
* The following minor changes are made for consistency between the
*    ICPSR & ANES versions of the data 
rename *, upper
capture gen CASEID = _n

* Clearer names for some variables
clonevar idnum = CASEID
clonevar wgtvar = V080102A

* All numeric MD codes are recoded to the Stata system missing value
quietly mvdecode _all, mv(-9/-1)

* Create race dichotomy
recode V081102 (1 = 1 "White")(. = .)(else = 0 "NonWhite"), gen(white) label (white)
recode white (1 = 0) if V081103 == 1
label variable white "Race recoded to 0 = NonWhite, 1 = White"
* More specifically, 1 = White Non-Hispanic, 0 = NonWhite and/or Hispanic

* Presidential vote -- only a few people voted for other candidates
* and they are recoded to missing
recode V085044A (1 = 1 "Obama") (3 = 0 "McCain") (else = .), gen(Obama) label(Obama)
label variable Obama "Who did R vote for in 2008? (0 = McCain, 1 = Obama)"

* Feminist Thermometer
clonevar feminist= V085064D
label variable feminist "Feeling thermometer: FEMINISTS"
 
* Bush thermometer
clonevar Bush = V085063A
label variable Bush "Feeling thermometer: President GW Bush"

* Age
clonevar age = V081104
label variable age "Age"

* Income. Ordinal categories are recoded to their midpoints, with the values
* capped at $150,000
 gen income = V083309A
 recode income (1=1.5)(2=4)(3=6.25)(4=8.75)(5=10.5)(6=11.75) ///
    (7=13.75)(8=16)(9=18.5)(10=21)(11=23.5)(12=27.5)(13=32.5)(14=37.5) ///
    (15=42.5)(16=47.5)(17=55)(18=67.5)(19=82.5)(20=95)(21=105)(22=115) ///
    (23=127.5)(24=142.5)(25=150) (98 = .)

* Rescale variables to make output easier to read
replace age = age/ 10.0
replace income = income/ 10.0
replace Bush = Bush/ 10.0
replace feminist = feminist/ 10.0
label variable income "Estimated Family Income in $10,000s"

order  Obama white age income Bush feminist idnum wgtvar

* We do not use weights in our analysis, but if they are used the changes in results
* are very minor. Weights perhaps should be used for other analyses,
* e.g. descriptive statistics
svyset idnum [pw = wgtvar]

* nested.ado does the actual analyes
nested Obama i.white age income Bush feminist, stub(Obama) description(Obama 2008 Presidential Vote) zshow